// This macro demonstrates how to erase non-circular objects

requires("1.29n");
run("Blobs (25K)");
setThreshold(125, 248);
run("Set Measurements...", "area perimeter circularity decimal=3");
run("Analyze Particles...", "minimum=1 maximum=999999 bins=20 show=Nothing clear record");

for (i=0; i<nResults; i++) {
    x = getResult('XStart', i);
    y = getResult('YStart', i);
    circularity = getResult('Circ.', i);
    if (circularity<0.85) {
        doWand(x,y);
        run("Clear");
    }
}

run("Select None");

